[ 作业提交 ] P5 Intro Course (03/24/2012 & 04/07/2012) DAY1 & DAY2

[RavenKwok]

请大家以回帖的形式提交第一以及第二天的作业，附上代码和显示窗口的效果图。提交的作业我会在下节课(04/14/2012)前审阅完毕。

[oncebjedi]

郭老师，上次的奇葩按钮代码如下


int wdt=100;
int hgt=50;
boolean btp=true;

void setup() {
  size(400, 400);
  background(255);
  smooth();
  frameRate(30);
  noStroke();
  fill(0);
}

void draw() {
    if (btp==true) {
      fill(255, 0, 255);
    }
    else {
      fill(0);
    }
    rect(200, 200, wdt, hgt);
}

void MousePressed() {
  if (mouseX>=200&&mouseX<=(200+wdt)&&mouseY>=200&&mouseY<=(200+hgt)) {
    btp=!btp;
  }
}

[RavenKwok]

mousePressed......你'm'大写了阿亲...- -

[oncebjedi]

 :oFML 老师看代码神速！

刚做了arc的练习，代码如下

程序代码

float diam;
float ellipseNoiseSeed;
float arcStart;
float arcEnd;
float arcNoiseSeed;
float xPos, yPos;

void setup() {
  size(400, 300);
  background(255);
  frameRate(30);
  smooth();
  noStroke();
  colorMode(HSB);
  ellipseMode(CENTER);
  ellipseNoiseSeed = random(10);
  arcNoiseSeed = random(10);
  diam = 20;
  yPos = xPos = diam/2;
}

void draw() {
  for(int i=0; i<20; i++) {
    for(int j=0; j<15; j++) {
      fill(noise(ellipseNoiseSeed)*360, 160, 255);
      ellipse(xPos+diam*i, yPos+diam*j, diam, diam);
      arcStart = random(0,2);
      arcEnd = random(0,2);
      arcStart = constrain(arcStart, 0, arcEnd);
      fill(noise(arcNoiseSeed)*360, 255, 255);
      arc(xPos+diam*i, yPos+diam*j, diam , diam, arcStart*PI, arcEnd*PI);
      ellipseNoiseSeed += 1;
      arcNoiseSeed += 1;
    }
  }
  noLoop();
}

void mousePressed() {
  ellipseNoiseSeed = random(10);
  arcNoiseSeed = random(10);
  loop();
}
  

效果图


上次另外一个躲避球作业让我再想想

PS玩论坛好复古！

[oncebjedi]

grainy screen
我坦白我不小心看到了上次作业的代码

程序代码

import processing.opengl.*;

void setup() {
  size(400, 400, OPENGL);
}

void draw() {
  for (int i=0; i<width; i++) {
    for (int j=0; j<height; j++) {
      stroke(random(255));
      point(i,j);
    }
  }
}

[RavenKwok]

arc 那个作业其实可以再申明一个cols 和rows 的整形值变量来指定矩阵的大小，而且可以通过场景宽度和高度除以圆的直径来动态获得cols 和rows，也就是说每次改变场景大小，矩阵都会填充满整个场景。

另外，可以试着把ellipseNoiseSeed，arcNoiseSeed 的增量再减小些，效果会更好一些

俺直接上代码了。

程序代码

float diam;
float ellipseNoiseSeed;
float arcStart;
float arcEnd;
float arcNoiseSeed;
float xPos, yPos;
int cols, rows;

void setup() {
  size(1200, 720);
  background(255);
  frameRate(30);
  smooth();
  noStroke();
  colorMode(HSB);
  ellipseMode(CENTER);
  ellipseNoiseSeed = random(10);
  arcNoiseSeed = random(10);
  diam = 16;
  yPos = xPos = diam/2;
  rows = ceil(height/diam);
  cols = ceil(width/diam);
}

void draw() {
  background(255);
  for(int i=0; i<cols; i++) {
    for(int j=0; j<rows; j++) {
      fill(noise(ellipseNoiseSeed)*360, 160, 255);
      ellipse(xPos+diam*i, yPos+diam*j, diam, diam);
      arcStart = random(0,PI);
      arcEnd = random(0,2*PI);
      arcStart = constrain(arcStart, 0, arcEnd);
      fill(noise(arcNoiseSeed)*360, 255, 255);
      arc(xPos+diam*i, yPos+diam*j, diam-2, diam-2, arcStart*PI, arcEnd*PI);
      ellipseNoiseSeed += 0.05;
      arcNoiseSeed += 0.05;
    }
  }
  noLoop();
}

void mousePressed() {
  ellipseNoiseSeed = random(10);
  arcNoiseSeed = random(10);
  loop();
}

[RavenKwok]

哈哈，论坛作为信息保留和交流分享的平台其实还是不错的。话说你雪花屏那个开OPENGL模式的想法是什么？

[oncebjedi]

因为渲染速度慢。。。

[RavenKwok]

使用P2D试试

[losangel9]

好的 会试试看

[Redshoes]

Raven 你好 day2的最后一个作业做来做去只做成这样

请问需要用到bezier曲线么？你的图是左右对称的吧，怎么做到那种一层层往里面缩小的效果的呢？

程序代码

float factor = 100;
float r,rRange;
float xPos,yPos;

void setup(){
  size(500,500);
  background(100);
  strokeWeight(1);
  stroke(255);
  frameRate(1);
  smooth();
  rRange = 350;
}

void draw(){
  translate(width/2,height/2);
  fill(random(255),random(255),random(255));
  beginShape();
  for(int degree = 0;degree<360;degree++){
  r = noise(factor)*rRange;
  xPos = cos(radians(degree))*r;
  yPos = sin(radians(degree))*r;
  factor += 0.05;
  curveVertex(xPos,yPos);
  }
  endShape(CLOSE);
  rRange -= 1 ;
}

呃，之后又看了你的博客，去查了那个代码，可是那个是x y轴都对称的。。只有y轴对称还是不会画，我可能太笨了。。。可以大体讲一下吗？一维二维三维noise生成的数字有什么区别呢？谢谢~~~~

[Redshoes]

已经自己做出来啦，嘿嘿

[Redshoes]

还是做错了。。。。

[RavenKwok]

@Redshoes

不好意思，很久没来看这个版块了。

各种维度的noise() 得到的值都是在0-1之间。

另外，你的r可以分为两块操作，一块是noiseR（控制自然的浮动），另一块是baseR（控制整体的大小）。

noiseR = (noise(factor)-0.5) * noiseRange;
baseR --;
r = baseR+noiseR;

这样的话，整个图形既有缩小的趋势，也会有比较明显的波动效果