用processing实现经典的水波效果

[vinjn]

附件中的完整工程包含下面的代码以及图片一张

程序代码

int Width = 800;
int Height = 600;
int FullSize = 0;
int Spacing = 10;

int[] source, dest;
PImage bg;

void setup()
{
  bg = loadImage("terminator_2.jpg");
  Width = bg.width;
  Height = bg.height;
  FullSize = Width * Height;
  size(Width, Height);
  source = new int[FullSize];
  dest = new int[FullSize];
  for (int i=0; i< FullSize; i++)
    source[i] = dest[i] = 0;
}

void draw()
{
  if (mousePressed)
  {
    if (mouseX > 0 && mouseX < Width && mouseY > 0 && mouseY < Height)
      source[mouseY*Width+mouseX] = (int)random(100, 5000);
  }
  for (int i=Width; i< FullSize-Width; i++)
  {
    // check for bounds
    int xi = i % Width;
    if ((xi==0) || (xi==Width-1)) continue;

    dest[i] = (
    ((source[i-1]+
      source[i+1]+
      source[i-Width]+
      source[i+Width]) >>1) ) -dest[i];

    dest[i] -= (dest[i] >> 5); // Damping - Quick divde by 32 (5 bits)
  }

  //image(bg, 0, 0);
  loadPixels();
  for (int i=Width; i< FullSize-Width; i++)
  {
    // check for bounds
    int xi = i % Width;
    if ((xi==0) || (xi==Width-1)) continue;

    int xoffset = dest[i-1] - dest[i+1];
    int yoffset = dest[i-Width] - dest[i+Width];

    int offset = i+xoffset+yoffset*Width;
    if (offset>0 && offset<FullSize)
      pixels[i] = bg.pixels[offset];
  }
  //bg.updatePixels();
  updatePixels();

  //swap
  int[] temp = source;
  source = dest;
  dest = temp;
}

[cs7258]

好东西学习下，as的水波很多，p5的这样效果少见

[vinjn]

原理都是一模一样的
是从as的例子移植的

[herohezi]

thanks in advance for your help

[George]

不错~！VJ就是喜欢折腾啊~！

[慕容苏媛]

那个我是新手，就是这个程序我试的时候是显示出错的。。不懂所以想问下。。谢谢啊

[RavenKwok]

@慕容苏媛

变量未声明。变量与系统变量重名。变量首字母不宜大写。

[vinjn]

那个我是新手，就是这个程序我试的时候是显示出错的。。不懂所以想问下。。谢谢啊

代码你都不读一下就运行啊？没用过loadImage么？
缺少图片啊朋友
请下载附件，而不是直接运行代码，我帖子第一句话就写清楚了，怎么都不看一下的

[RavenKwok]

@vinjn

原来能直接用Width,Height 指定。。。。。。- -

[慕容苏媛]

我错了。。。能不能问下，假如我用processing编程画了一个圆，我要是想用Arduino 双轴按键摇杆通过arduino控制processing窗口内的圆移动要怎么编啊。。万分感谢。。求助。。。